//*****************************************************************************
//                         でるもんたの HTML 補助モード                        
//*****************************************************************************
$RCSID = "$Id: ds_html.mac 1.5 2005/06/12 10:58:21 delmonta Exp $";
//-------------------------------- データの定義 -------------------------------
$Tag['1']="h1";
$Tag['2']="h2";
$Tag['3']="h3";
$Tag['4']="h4";
$Tag['5']="h5";
$Tag['6']="h6";
$Tag['a']="a";		$Parameter['a']="href=\"\" name=\"\"";
$Tag['b']="b";
$Tag['B']="blockquote";
$Tag['c']="code";
$Tag['C']="center";
$Tag['e']="em";
$Tag['f']="font";	$Parameter['f']="color=\"\"";
$Tag['i']="i";
$Tag['k']="kbd";
$Tag['n']="nobr";
$Tag['O']="ol";
$Tag['p']="pre";
$Tag['R']="ruby";
$Tag['s']="strong";
$Tag['S']="select";
$Tag['t']="tt";
$Tag['u']="u";
$Tag['U']="ul";
$Tag['x']="s";
$Tag['^']="sup";
$Tag['_']="sub";
$Tag['+']="big";
$Tag['-']="small";
//------------------------------- メインルーチン ------------------------------
main:
	#c = inputchar("でるもんたの HTML 補助モード "+$RCSID);

	if	(#c=='B'-64) beginsel;
	else if	(#c=='O'-64) {#c=inputchar(""); endmacro;}
	else if	(#c==0x1B) escape;

	else if	(#c==0x1C || #c=='S'-64) left;
	else if	(#c==0x1D || #c=='E'-64) up;
	else if	(#c==0x1E || #c=='D'-64) right;
	else if	(#c==0x1F || #c=='X'-64) down;

	else if	(#c=='F'-64) golineend;
	else if	(#c=='A'-64) golinetop;
	else if	(#c=='C'-64) nextpage;
	else if	(#c=='R'-64) prevpage;

	else if	(#c=='H'-64) backspace;
	else if (#c==' '   ) insert " ";
	else if (#c=='I'-64) insert "\t";
	else if (#c=='M'-64) insert "\n";
	else if (#c==0x7f) delete;

	else if (#c=='U'-64) undo;

	else if	($Tag[#c]!="")   call insert_tag $Tag[#c], $Parameter[#c];
	else if (#c=='A' ) call anchor_with_dup;
	else if	(#c=='M' ) call insert_matrix;
	else if (#c=='T' ) call table;
	else if (#c=='#' ) call type_any_key;

	else if (#c=='&' ) call quote_metacharacter;
	else if (#c=='%' ) call quote_if_necessary;
	else if (#c=='$' ) call quote_always;
	else if (#c=='\\') call quote_2nd_5C;

	else if (#c=='I' ) insert "<input type= name= size= value= checked>";
	else if (#c=='l' ) insert "<li>";;
	else if (#c=='o' ) insert "<option>";

	else if	(#c=='<' ) insert "<!--";
	else if	(#c=='>' ) insert "-->";
	else if (#c=='/' ) insert "<br>";
	else if (#c=='w' ) insert "<wbr>";

	else if	(#c=='0' ) call insert_tag "","";

	else	message "Key=" + str(#c);
goto main;

//--------------------------------- タグを挿入 --------------------------------
// $$1 : 挿入すべきタグ名
// $$2 : タグのパラメータ
//-----------------------------------------------------------------------------
insert_tag:
	$$tag_to_insert = $$1;
	$$argument      = $$2;
	if	($$tag_to_insert=="")
		#stackpointer = 0;
	else if(#stackpointer>0 && $TagStack[#stackpointer-1]==$$tag_to_insert)
	{
		#stackpointer = #stackpointer-1;
		if	($$tag_to_insert=="ruby")
			insert "<rp>（</rp><rt>　</rt><rp>）</rp></ruby>";
		else
			insert "</"+$$tag_to_insert+">";
	}
	else
	{
		$TagStack[#stackpointer]=$$tag_to_insert;
		#stackpointer = #stackpointer+1;

		insert "<"+$$tag_to_insert;
		if	($$argument!="")
			insert " "+$$argument;
		insert ">";
	}
return;
//---------------------------- 行列用のデータの挿入 ---------------------------
insert_matrix:
	$$size = input("行列の行数は？","2");

	if	($$size=="")
		return;

	insert
		"\t<tr align=\"center\">\n" + 
		"\t\t<!-- (  ) -->\n" +
		"\t\t<td rowspan=" + $$size + ">* =</td>\n" +
		"\t\t<td rowspan=" + $$size + "><font size=7>(</font></td>\n" +

		"\t\t\t<td></td>\n" +
		"\t\t\t<td></td>\n" +

		"\t\t<td rowspan=" + $$size + "><font size=7>)</font></td>\n" +
		"\t\t<td rowspan=" + $$size + "> + </td>\n" +
		
		"\t<tr align=\"center\">\n" +
		"\t\t<td></td>\n" +
		"\t\t<td></td>\n";
return;
//----------------------------- 特殊文字のクォート ----------------------------
quote_metacharacter:
	if      (code==ascii("&" )) {delete; insert "&amp;" ;}
	else if (code==ascii("<" )) {delete; insert "&lt;"  ;}
	else if (code==ascii(">" )) {delete; insert "&gt;"  ;}
	else if (code==ascii("\"")) {delete; insert "&quot;";}
	else
	{
		message "この文字は & でクォートする必要はありません。";
	}
return;
//------------- 書いてある URL を href の引数にして A タグを入れる ------------
anchor_with_dup:
	if	(!selecting)
	{
		message "範囲選択してからこのコマンドを入力してください。";
		return;
	}

	// このへん、cut して paste/poppaste を使うのが簡単だが、
	// 秀丸が常駐していないと使えないのでこの方法を採用。


	$$url = gettext(seltopx,seltopy,selendx,selendy);
	moveto seltopx,seltopy;
	##ex = selendx; ##ey = selendy;	// beginsel すると消えるので、保存
	beginsel;
	moveto ##ex, ##ey;
	delete;

	insert "<a href=\""+$$url+"\">"+$$url+"</a>";
return;
//--------------------------- 文字を % で quote する --------------------------
quote_if_necessary:
	// !"#'),-.:;? の 11 種の文字は、URL の最後に来た場合のみ
	// quote の必要があるので、とりあえずここでは対象から外しておく
	if	(strstr("%&+ <>]`}",char(code%256))==-1)
		right;
	else
		call quote_always;
return;

quote_always:
	##code = code;
	delete;
	if	(##code>=256)
	{
		insert "%"+rightstr("0"+hex(##code/256),2);
	}

	insert "%"+rightstr("0"+hex(##code%256),2);
return;
//-------- HTML とは関係ないが 2 バイト目が 0x5C('\') になる文字の対策 --------
quote_2nd_5C:
	if	(selecting)
	{
		replaceallfast "[―�\ソЫ�\�\�\�\噂浬欺圭構蚕十申曾箪貼能暴"+
			"予禄兔喀媾彌拿杤歃濬畚秉綵臀藹觸軆鐔饅鷭�\�\�\�\�\]",
			"\\0\\\\", regular, inselect;
	}
	else if	(code%256==0x5C && code!=0x5C)
	{
		right;
		insert "\\";
	}
	else
		right;
return;
//------------------------------- テーブルの処理 ------------------------------
table:
	$$menu[0] = "&A	<table>";
	$$menu[1] = "&B	<tbody>";
	$$menu[2] = "&R	<tr>";
	$$menu[3] = "&H	<th>";
	$$menu[4] = "&D	<td>";
	$$menu[5] = "&/	</Txxxx>";

	menuarray $$menu, 6;
	if   (result==1) insert "<table border=1 cellspacing=0 cellpadding=3>";
	else if	(result==2) insert "<tbody>";
	else if	(result==3) insert "<tr>";
	else if	(result==4) insert "<th>";
	else if	(result==5) insert "<td>";
	else if	(result==6)
	{
		$$menu[0] = "&A	</table>";
		$$menu[1] = "&B	</tbody>";
		$$menu[2] = "&R	</tr>";
		$$menu[3] = "&H	</th>";
		$$menu[4] = "&D	</td>";
		menuarray $$menu,5;
		if	(result==1) insert "</table>";
		else if	(result==2) insert "</tbody>";
		else if	(result==3) insert "</tr>";
		else if	(result==4) insert "</th>";
		else if	(result==5) insert "</td>";
	}
return;
//------------------------------ 任意のキーの入力 -----------------------------
type_any_key:
	##c = inputchar("任意の1文字を入力してください。");
	if (##c != 27)
		insert char(##c);

return;
//-------------------------------- End of file --------------------------------